blob: a65b271819b7d94ffeb436c6ac965fdb33a76259 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
/*
* Linker script for RISC-V SBI images
*
*/
SECTIONS {
/* Start at virtual address zero */
. = 0;
/* Weak symbols that need zero values if not otherwise defined */
.weak 0x0 : {
_weak = .;
*(.weak)
*(.weak.*)
_eweak = .;
}
_assert = ASSERT ( ( _weak == _eweak ), ".weak is non-zero length" );
/* Prefix code */
.prefix : {
_prefix = .;
*(.prefix)
*(.prefix.*)
_eprefix = .;
}
/* Program code */
.text : {
_text = .;
*(.text)
*(.text.*)
_etext = .;
}
/* Align to page size to allow linker to generate W^X segments */
. = ALIGN ( 4096 );
/* Read-only data */
.rodata : {
_rodata = .;
*(.rodata)
*(.rodata.*)
_erodata = .;
}
/* Writable data */
.data : {
_data = .;
*(.data)
*(.data.*)
KEEP(*(SORT(.tbl.*))) /* Various tables. See include/tables.h */
KEEP(*(.provided))
KEEP(*(.provided.*))
_edata = .;
}
/* Uninitialised and discardable data */
OVERLAY : {
/* Runtime relocations (discarded after use) */
.rela.dyn {
_reloc = .;
*(.rela)
*(.rela.dyn)
}
/* Compressor information block */
.zinfo {
_zinfo = .;
KEEP(*(.zinfo))
KEEP(*(.zinfo.*))
_ezinfo = .;
}
/* Uninitialised data */
.bss {
_bss = .;
*(.bss)
*(.bss.*)
*(COMMON)
*(.stack)
*(.stack.*)
/* Align to allow for easy zeroing by prefix code */
. = ALIGN ( 16 );
_ebss = .;
}
}
/* Calculate end of relocations
*
* This cannot be done by placing "_ereloc = .;" inside the
* .rela.dyn section, since the dynamic relocations are not
* present in the input sections but are instead generated during
* linking.
*/
_ereloc = ( _reloc + __load_stop_reladyn - __load_start_reladyn );
/* Length of initialised data */
_sbi_filesz = ABSOLUTE ( _ereloc );
/* Unwanted sections */
/DISCARD/ : {
*(.comment)
*(.comment.*)
*(.note)
*(.note.*)
*(.eh_frame)
*(.eh_frame.*)
*(.dynamic)
*(.dynsym)
*(.dynstr)
*(.einfo)
*(.einfo.*)
*(.discard)
*(.discard.*)
*(.pci_devlist.*)
}
}
|
