blob: a65136d00882ea989d154cb52e76495f7d6e7845 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
// Rom layout and bios assembler to C interface.
//
// Copyright (C) 2009-2012 Kevin O'Connor <kevin@koconnor.net>
//
// This file may be distributed under the terms of the GNU LGPLv3 license.
#include "config.h" // CONFIG_*
#include "entryfuncs.S" // ENTRY_*
/****************************************************************
* Rom Header
****************************************************************/
.section .rom.header
.code16gcc
.global _rom_header, _rom_header_size, _rom_header_checksum
_rom_header:
.word 0xaa55
_rom_header_size:
.byte 0
_rom_header_entry:
jmp _optionrom_entry
_rom_header_checksum:
.byte 0
_rom_header_other:
.space 17
_rom_header_pcidata:
#if CONFIG_VGA_PCI == 1
.word rom_pci_data
#else
.word 0
#endif
_rom_header_pnpdata:
.word 0
_rom_header_other2:
.word 0
_rom_header_signature:
.asciz "IBM"
/****************************************************************
* Entry points
****************************************************************/
// This macro is the same as ENTRY_ARG except the "calll"
// instruction is avoided to work around known issues in the
// emulation of some versions of x86emu.
.macro ENTRY_ARG_VGA cfunc
cli
cld
PUSHBREGS
movw %ss, %ax // Move %ss to %ds
movw %ax, %ds
movl %esp, %ebx // Backup %esp, then zero high bits
movzwl %sp, %esp
movl %esp, %eax // First arg is pointer to struct bregs
pushw %ax ; callw \cfunc
movl %ebx, %esp // Restore %esp (including high bits)
POPBREGS
.endm
DECLFUNC entry_104f05
entry_104f05:
ENTRY_ARG_VGA vbe_104f05
lretw
DECLFUNC _optionrom_entry
_optionrom_entry:
ENTRY_ARG_VGA vga_post
lretw
DECLFUNC entry_10
entry_10:
ENTRY_ARG_VGA handle_10
iretw
|
